#Gibbs sampler for the Bayesian binomial logit-normal mixed effects model
#WinBUGS code
#

#The paper that describes this methodology: B. T. McClintock and
#J. A. Hoeting, "Bayesian analysis of abundance for binomial sighting
#data with unknown number of marked individuals", submitted.  Paper
#available from the authors upon request.

#Model specification for BBLNE without individual heterogeneity

model	{
	mu~dunif(0,1)
	psi~dunif(0,1)
	for(s in 1:M)	{
    		q[s]~dbin(psi,1)
    		pq[s]<-mu*q[s]
    		y[s]~dbin(pq[s],k)
	}
	n<-sum(q[])

	#Specify allowable positive discrete values for U 
	for(j in 1:maxU)	{
		Uprob[j]<- 1/maxU
	}
	U~dcat(Uprob[])

	#Use 'zero trick' for Jeffrey's prior on U
	zero<-0
	phi<- -log(1/U)
	zero~dpois(phi)

	Uk<-U*k
	T~dbin(mu,Uk)
	N<-U+n
}


#Model specification for BBLNE with individual heterogeneity:

model	{
	tau<-1/0.25
	a<-0.5
	b<-0.5
	beta~dnorm(0,tau)
	sigma2~dgamma(a,b)
	taup<-1/sigma2
	psi~dunif(0,1)
	for(s in 1:M)	{
     		q[s]~dbin(psi,1)
		theta[s]~dnorm(beta,taup)
		logit(p[s])<-theta[s]
		pq[s]<-p[s]*q[s]
		y[s]~dbin(pq[s],k)
	}
	n<-sum(q[])
	mu<-1/(1+exp(-beta))

	#Specify allowable positive discrete values for U 
	for(j in 1:maxU)	{
		Uprob[j]<- 1/maxU
	}
	U~dcat(Uprob[])

	#Use 'zero trick' to specify Jeffrey's prior on U
	zero<-0
	phi<- -log(1/U)
	zero~dpois(phi)

	Uk<-U*k
	T~dbin(mu,Uk)
	N<-U+n
}

#New Zealand Robin Data
list(y=c(3,1,2,1,1,3,2,1,3,1,3,5,1,1,4,5,3,6,2,2,5,5,5,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0),M=80,k=7,T=45,maxU=100)